SN-YO: Surya Namaskar Yoga Ontology

Semantic Modeling | OWL | SPARQL

This ontology models Surya Namaskar as asanas, numbered pose occurrences, and sequence variants. It supports structured querying of sequence order, repeated poses, inverse relationships, support type, mantra, chakra,body parts, breathing patterns, safety notes and shared asanas across variants.

The ontology also includes a pose correction layer for the Base Surya Namaskar followed at IIT BHU. This layer models pose errors and correction instructions.

Ontology Overview

Classes

Pose

Represents one numbered occurrence of an asana within a variant sequence.

Asana

Represents a yoga asana identity independent of sequence position.

Variant

Represents a Surya Namaskar tradition or sequence variant.

BodyPart

Represents a body part involved in a pose.

BreathingPattern

Represents the breathing pattern associated with a pose.

PoseError

Represents a possible error while performing a pose.

CorrectionInstruction

Represents a correction instruction linked to an error.

Object Properties

hasAsana

Links a pose occurrence to the asana performed.

belongsToVariant

Links a pose to its Surya Namaskar variant.

hasNextPose

Links a pose to the next pose in the sequence.

hasPreviousPose

Links a pose to the previous pose in the sequence.

repeatsPose

Links poses that are repeated within a sequence.

hasInversePose

Links poses that are inverse to each other.

sameAsanaAs

Links equivalent or normalized asana identities.

involvesBodyPart

Links a pose to the body parts involved.

hasBreathingPattern

Links a pose to its associated breathing pattern.

hasPossibleError

Links a pose to possible performance errors.

hasCorrection

Links a pose error to its correction instruction.

Datatype Properties

Pose Attributes

poseNumber, hasMantra, hasChakra, hasSupportType, hasLaterality

Error & Correction Descriptions

errorDescription, correctionText, hasSafetyNote

Project Files

Ontology File

Main OWL ontology file for Surya Namaskar.

Download OWL

pyLODE Documentation

Generated ontology documentation for classes, properties, and metadata.

View Docs

GitHub Repository

Source code, ontology files, images, and project structure.

View Repo

Ontology Metadata

Title Surya Namaskar Ontology

Format OWL (RDF/XML)

Registered Namespaces

core: https://purl.org/ai4s/yoga/sn-yo/core#
base: https://purl.org/ai4s/yoga/sn-yo/base-sn#
v1: https://purl.org/ai4s/yoga/sn-yo/variant01#
v2: https://purl.org/ai4s/yoga/sn-yo/variant02#
v3: https://purl.org/ai4s/yoga/sn-yo/variant03#

Variants Represented

BaseSN_SivanandaYogaVedantaCentre_UsedatIITBHU Variant01_KrishnamacharyaVinyasa Variant02_BiharSchoolOfYoga Variant03_SwamiVivekanandaKendra

Use Cases

⚖️

Compare Surya Namaskar variants across traditions.

🔁

Identify repeated poses and inverse pose relationships.

🔢

Retrieve the ordered sequence of poses in Base Surya Namaskar.

🧘

Query poses based on standing posture and support types.

📿

Retrieve mantra and chakra metadata for Base SN poses.

🔗

Identify primary asanas shared across multiple variants.

🔍

Retrieve pose errors, body parts, breathing patterns, safety notes, and corrections.

📊

Support competency-question based evaluation using SPARQL queries.

Competency Questions & SPARQL Queries

Interactive exploration of Competency Questions and their corresponding SPARQL queries. Click to expand and view the evaluated results.

CQ1: What are the poses in Base Surya Namaskar?

▼

PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX core: <https://purl.org/ai4s/yoga/sn-yo/core#>
PREFIX base: <https://purl.org/ai4s/yoga/sn-yo/base-sn#>
PREFIX v1: <https://purl.org/ai4s/yoga/sn-yo/variant01#>
PREFIX v2: <https://purl.org/ai4s/yoga/sn-yo/variant02#>
PREFIX v3: <https://purl.org/ai4s/yoga/sn-yo/variant03#>
SELECT ?pose
WHERE {
  ?pose rdf:type core:Pose ;
        core:belongsToVariant base:BaseSN_SivanandaYogaVedantaCentre_UsedatIITBHU .
}
ORDER BY ?pose

Execution Result

?pose (base-sn namespace)
BaseSN_Pose01
BaseSN_Pose02
BaseSN_Pose03
BaseSN_Pose04
BaseSN_Pose05
BaseSN_Pose06
BaseSN_Pose07
BaseSN_Pose08
BaseSN_Pose09
BaseSN_Pose10
BaseSN_Pose11
BaseSN_Pose12

CQ2: How many poses are in Base Surya Namaskar?

▼

PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX core: <https://purl.org/ai4s/yoga/sn-yo/core#>
PREFIX base: <https://purl.org/ai4s/yoga/sn-yo/base-sn#>
PREFIX v1: <https://purl.org/ai4s/yoga/sn-yo/variant01#>
PREFIX v2: <https://purl.org/ai4s/yoga/sn-yo/variant02#>
PREFIX v3: <https://purl.org/ai4s/yoga/sn-yo/variant03#>

SELECT (COUNT(?pose) AS ?count)
WHERE {
  ?pose rdf:type core:Pose ;
        core:belongsToVariant base:BaseSN_SivanandaYogaVedantaCentre_UsedatIITBHU .
}

Execution Result

?count
12

CQ3: Which poses are performed standing on two feet in Base Surya Namaskar?

▼

PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX core: <https://purl.org/ai4s/yoga/sn-yo/core#>
PREFIX base: <https://purl.org/ai4s/yoga/sn-yo/base-sn#>
PREFIX v1: <https://purl.org/ai4s/yoga/sn-yo/variant01#>
PREFIX v2: <https://purl.org/ai4s/yoga/sn-yo/variant02#>
PREFIX v3: <https://purl.org/ai4s/yoga/sn-yo/variant03#>
SELECT ?pose
WHERE {
  ?pose rdf:type core:Pose ;
        core:belongsToVariant base:BaseSN_SivanandaYogaVedantaCentre_UsedatIITBHU ;
        core:hasSupportType "StandingTwoFeet" .
}
ORDER BY ?pose

Execution Result

?pose
BaseSN_Pose01
BaseSN_Pose02
BaseSN_Pose11
BaseSN_Pose12

CQ4: Which poses are repeated in Base Surya Namaskar?

▼

PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX core: <https://purl.org/ai4s/yoga/sn-yo/core#>
PREFIX base: <https://purl.org/ai4s/yoga/sn-yo/base-sn#>
PREFIX v1: <https://purl.org/ai4s/yoga/sn-yo/variant01#>
PREFIX v2: <https://purl.org/ai4s/yoga/sn-yo/variant02#>
PREFIX v3: <https://purl.org/ai4s/yoga/sn-yo/variant03#>
SELECT ?pose ?repeatedPose
WHERE {
  ?pose core:belongsToVariant base:BaseSN_SivanandaYogaVedantaCentre_UsedatIITBHU ;
        core:repeatsPose ?repeatedPose ;
        core:poseNumber ?poseNum .

  ?repeatedPose core:poseNumber ?repeatedNum .

  FILTER(?poseNum < ?repeatedNum)
}
ORDER BY ?poseNum

Execution Result

?pose	?repeatedPose
BaseSN_Pose01	BaseSN_Pose12
BaseSN_Pose02	BaseSN_Pose11
BaseSN_Pose03	BaseSN_Pose10
BaseSN_Pose04	BaseSN_Pose09

CQ5: Which poses have inverse relationships in Base Surya Namaskar?

▼

PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX core: <https://purl.org/ai4s/yoga/sn-yo/core#>
PREFIX base: <https://purl.org/ai4s/yoga/sn-yo/base-sn#>
PREFIX v1: <https://purl.org/ai4s/yoga/sn-yo/variant01#>
PREFIX v2: <https://purl.org/ai4s/yoga/sn-yo/variant02#>
PREFIX v3: <https://purl.org/ai4s/yoga/sn-yo/variant03#>

SELECT ?pose ?inversePose
WHERE {
?pose core:belongsToVariant base:BaseSN_SivanandaYogaVedantaCentre_UsedatIITBHU ;
core:hasInversePose ?inversePose ;
core:poseNumber ?poseNum .

?inversePose core:poseNumber ?inverseNum .

FILTER(?poseNum < ?inverseNum)
}
ORDER BY ?poseNum

Execution Result

?pose	?inversePose
BaseSN_Pose04	BaseSN_Pose09

CQ6: Which asanas are shared across multiple variants?

▼

PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX core: <https://purl.org/ai4s/yoga/sn-yo/core#>
PREFIX base: <https://purl.org/ai4s/yoga/sn-yo/base-sn#>
PREFIX v1: <https://purl.org/ai4s/yoga/sn-yo/variant01#>
PREFIX v2: <https://purl.org/ai4s/yoga/sn-yo/variant02#>
PREFIX v3: <https://purl.org/ai4s/yoga/sn-yo/variant03#>

SELECT ?asana (COUNT(DISTINCT ?variant) AS ?varCount)
WHERE {
  ?pose rdf:type core:Pose ;
        core:hasAsana ?asana ;
        core:belongsToVariant ?variant .
}
GROUP BY ?asana
HAVING (COUNT(DISTINCT ?variant) > 1)
ORDER BY DESC(?varCount) ?asana

Execution Result

?asana	?varCount
Pranamasana	3
HastaUtthanasana	3
Padahastasana	3
AshwaSanchalanasana	3
Bhujangasana	3
Parvatasana	3
ChaturangaDandasana	2
AshtangaNamaskara	2

CQ7: What is the sequence order of poses in Base Surya Namaskar?

▼

PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX core: <https://purl.org/ai4s/yoga/sn-yo/core#>
PREFIX base: <https://purl.org/ai4s/yoga/sn-yo/base-sn#>
PREFIX v1: <https://purl.org/ai4s/yoga/sn-yo/variant01#>
PREFIX v2: <https://purl.org/ai4s/yoga/sn-yo/variant02#>
PREFIX v3: <https://purl.org/ai4s/yoga/sn-yo/variant03#>
SELECT ?pose ?nextPose
WHERE {
  ?pose core:belongsToVariant base:BaseSN_SivanandaYogaVedantaCentre_UsedatIITBHU ;
        core:hasNextPose ?nextPose .
}
ORDER BY ?pose

Execution Result

?pose	?nextPose
BaseSN_Pose01	BaseSN_Pose02
BaseSN_Pose02	BaseSN_Pose03
BaseSN_Pose03	BaseSN_Pose04
BaseSN_Pose04	BaseSN_Pose05
BaseSN_Pose05	BaseSN_Pose06
BaseSN_Pose06	BaseSN_Pose07
BaseSN_Pose07	BaseSN_Pose08
BaseSN_Pose08	BaseSN_Pose09
BaseSN_Pose09	BaseSN_Pose10
BaseSN_Pose10	BaseSN_Pose11
BaseSN_Pose11	BaseSN_Pose12

CQ8: Which common errors can occur in each pose of Base Surya Namaskar, and how can they be corrected?

▼

PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX core: <https://purl.org/ai4s/yoga/sn-yo/core#>
PREFIX base: <https://purl.org/ai4s/yoga/sn-yo/base-sn#>
PREFIX v1: <https://purl.org/ai4s/yoga/sn-yo/variant01#>
PREFIX v2: <https://purl.org/ai4s/yoga/sn-yo/variant02#>
PREFIX v3: <https://purl.org/ai4s/yoga/sn-yo/variant03#>

SELECT ?pose ?asana ?error ?instruction
WHERE {
  ?pose core:belongsToVariant base:BaseSN_SivanandaYogaVedantaCentre_UsedatIITBHU ;
        core:hasAsana ?asana ;
        core:hasPossibleError ?error .

  ?error core:hasCorrection ?instruction .
}
ORDER BY ?pose ?error

Execution Result

Pose	Asana	Error	Instruction
BaseSN_Pose01	Pranamasana	CollapsedChestError	LiftChestForwardUpwardInstruction
BaseSN_Pose01	Pranamasana	CollapsedChestError	LiftChestInstruction
BaseSN_Pose01	Pranamasana	CollapsedChestError	LiftChestForwardInstruction
BaseSN_Pose01	Pranamasana	PalmsMisalignedError	AlignPalmsAtChestInstruction
BaseSN_Pose01	Pranamasana	RoundedShouldersError	RelaxShouldersInstruction
BaseSN_Pose01	Pranamasana	UnevenWeightError	BalanceWeightEvenlyInstruction
BaseSN_Pose02	HastaUtthanasana	BentArmsError	KeepArmsStraightInstruction
BaseSN_Pose02	HastaUtthanasana	LowerBackOverarchingError	LiftUpwardFirstInstruction
BaseSN_Pose02	HastaUtthanasana	LowerBackOverarchingError	LengthenSpineInstruction
BaseSN_Pose02	HastaUtthanasana	LowerBackOverarchingError	GentleBackbendInstruction
BaseSN_Pose02	HastaUtthanasana	NeckStrainError	LengthenSpineInstruction
BaseSN_Pose02	HastaUtthanasana	RaisedShouldersError	RelaxShouldersInstruction
BaseSN_Pose03	Padahastasana	ExcessiveKneeBendError	SoftenKneesInstruction
BaseSN_Pose03	Padahastasana	RoundedBackError	BendFromHipsInstruction
BaseSN_Pose03	Padahastasana	RoundedBackError	LengthenSpineInstruction
BaseSN_Pose03	Padahastasana	WeightOnHeelsOnlyError	DistributeWeightEvenlyInstruction
BaseSN_Pose04	AshwaSanchalanasana	CollapsedChestError	LiftChestForwardUpwardInstruction
BaseSN_Pose04	AshwaSanchalanasana	CollapsedChestError	LiftChestInstruction
BaseSN_Pose04	AshwaSanchalanasana	CollapsedChestError	LiftChestForwardInstruction
BaseSN_Pose04	AshwaSanchalanasana	KneeBeyondAnkleError	AlignFrontKneeInstruction
BaseSN_Pose04	AshwaSanchalanasana	WeakBackLegError	ExtendBackLegInstruction
BaseSN_Pose05	ChaturangaDandasana	ElbowsFlaredError	TuckElbowsInstruction
BaseSN_Pose05	ChaturangaDandasana	RaisedHipsError	KeepBodyAlignedInstruction
BaseSN_Pose05	ChaturangaDandasana	SaggingHipsError	EngageCoreInstruction
BaseSN_Pose05	ChaturangaDandasana	SaggingHipsError	KeepBodyAlignedInstruction
BaseSN_Pose06	AshtangaNamaskara	ChestNotLoweredError	LowerChestProperlyInstruction
BaseSN_Pose06	AshtangaNamaskara	ElbowsWideError	KeepElbowsCloseInstruction
BaseSN_Pose06	AshtangaNamaskara	HipsDroppedFullyError	MaintainHipPositionInstruction
BaseSN_Pose07	Bhujangasana	CompressedLowerBackError	LengthenSpineInstruction
BaseSN_Pose07	Bhujangasana	OverextensionError	GentleBackbendInstruction
BaseSN_Pose07	Bhujangasana	ShoulderTensionError	RelaxShouldersInstruction
BaseSN_Pose08	Parvatasana	RoundedBackError	BendFromHipsInstruction
BaseSN_Pose08	Parvatasana	RoundedBackError	LengthenSpineInstruction
BaseSN_Pose08	Parvatasana	UnstableLegsError	StabilizeLegsInstruction
BaseSN_Pose08	Parvatasana	WristOverloadError	PushHipsUpwardInstruction
BaseSN_Pose08	Parvatasana	WristOverloadError	DistributeWeightEvenlyInstruction
BaseSN_Pose09	AshwaSanchalanasana	CollapsedChestError	LiftChestForwardUpwardInstruction
BaseSN_Pose09	AshwaSanchalanasana	CollapsedChestError	LiftChestInstruction
BaseSN_Pose09	AshwaSanchalanasana	CollapsedChestError	LiftChestForwardInstruction
BaseSN_Pose09	AshwaSanchalanasana	KneeBeyondAnkleError	AlignFrontKneeInstruction
BaseSN_Pose09	AshwaSanchalanasana	WeakBackLegError	ExtendBackLegInstruction
BaseSN_Pose10	Padahastasana	ExcessiveKneeBendError	SoftenKneesInstruction
BaseSN_Pose10	Padahastasana	RoundedBackError	BendFromHipsInstruction
BaseSN_Pose10	Padahastasana	RoundedBackError	LengthenSpineInstruction
BaseSN_Pose11	HastaUtthanasana	CompressedLowerBackError	LengthenSpineInstruction
BaseSN_Pose11	HastaUtthanasana	ShoulderTensionError	RelaxShouldersInstruction
BaseSN_Pose12	Pranamasana	CollapsedPostureError	CenterBodyInstruction
BaseSN_Pose12	Pranamasana	CollapsedPostureError	LiftChestInstruction
BaseSN_Pose12	Pranamasana	PoorBalanceError	CenterBodyInstruction

CQ9: What are the poses in the Base Surya Namaskar sequence, along with their associated asanas, breathing patterns, and safety notes?

▼

PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX core: <https://purl.org/ai4s/yoga/sn-yo/core#>
PREFIX base: <https://purl.org/ai4s/yoga/sn-yo/base-sn#>
PREFIX v1: <https://purl.org/ai4s/yoga/sn-yo/variant01#>
PREFIX v2: <https://purl.org/ai4s/yoga/sn-yo/variant02#>
PREFIX v3: <https://purl.org/ai4s/yoga/sn-yo/variant03#>

SELECT ?poseNumber ?pose ?asana ?breathing ?safetyNote
WHERE {
  ?pose rdf:type core:Pose ;
        core:belongsToVariant base:BaseSN_SivanandaYogaVedantaCentre_UsedatIITBHU ;
        core:poseNumber ?poseNumber ;
        core:hasAsana ?asana ;
        core:hasBreathingPattern ?breathing ;
        core:hasSafetyNote ?safetyNote .
}
ORDER BY ?poseNumber

Execution Result

Pose Number	Pose	Asana	Breathing	Safety Note
1	BaseSN_Pose01	Pranamasana	Exhale	Stand upright with balanced weight and avoid locking the knees.
2	BaseSN_Pose02	Hasta Utthanasana	Inhale	Lift the chest upward with control and avoid compressing the lower back during the backbend.
3	BaseSN_Pose03	Padahastasana	Exhale	Avoid deep forward bending in case of back pain or tight hamstrings; keep the knees slightly bent and spine long.
4	BaseSN_Pose04	Ashwa Sanchalanasana	Inhale	Keep the front knee aligned over the ankle and place the back knee gently on the floor.
5	BaseSN_Pose05	Chaturanga Dandasana	Hold	Maintain a straight body line from head to heels and avoid sagging or lifting the hips excessively.
6	BaseSN_Pose06	Ashtanga Namaskara	Exhale	Lower the body gradually with control and distribute weight evenly across the eight contact points.
7	BaseSN_Pose07	Bhujangasana	Inhale	Lift the chest gently without forcing the backbend and keep the shoulders relaxed.
8	BaseSN_Pose08	Parvatasana	Exhale	Lengthen the spine and avoid rounding the back; press the heels down gently without forcing.
9	BaseSN_Pose09	Ashwa Sanchalanasana	Inhale	Step forward smoothly and ensure proper alignment of the front knee over the ankle.
10	BaseSN_Pose10	Padahastasana	Exhale	Move into the forward bend with control and avoid overstretching the hamstrings.
11	BaseSN_Pose11	Hasta Utthanasana	Inhale	Rise upward with control and extend the chest without collapsing into the lower back.
12	BaseSN_Pose12	Pranamasana	Exhale	Return to a steady standing posture and maintain relaxed, even breathing.

CQ10: Do the same asanas appear at different pose numbers in different Surya Namaskar variants?

▼

PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX core: <https://purl.org/ai4s/yoga/sn-yo/core#>
PREFIX base: <https://purl.org/ai4s/yoga/sn-yo/base-sn#>
PREFIX v1: <https://purl.org/ai4s/yoga/sn-yo/variant01#>
PREFIX v2: <https://purl.org/ai4s/yoga/sn-yo/variant02#>
PREFIX v3: <https://purl.org/ai4s/yoga/sn-yo/variant03#>

SELECT ?asana ?variant
       (GROUP_CONCAT(DISTINCT STR(?poseNumber); separator=", ") AS ?poseNumbers)
WHERE {
  ?pose rdf:type core:Pose ;
        core:hasAsana ?asana ;
        core:belongsToVariant ?variant ;
        core:poseNumber ?poseNumber .
}
GROUP BY ?asana ?variant
ORDER BY ?asana ?variant

Execution Result

?asana	?variant	?poseNumbers
Adho Mukha Svanasana	Variant01_KrishnamacharyaVinyasa	9
Ashtanga Namaskara	BaseSN_SivanandaYogaVedantaCentre_UsedatIITBHU	6
Ashtanga Namaskara	Variant02_BiharSchoolOfYoga	6
Ashwa Sanchalanasana	BaseSN_SivanandaYogaVedantaCentre_UsedatIITBHU	9, 4
Ashwa Sanchalanasana	Variant02_BiharSchoolOfYoga	4, 9
Ashwa Sanchalanasana	Variant03_SwamiVivekanandaKendra	3, 10
Bhujangasana	BaseSN_SivanandaYogaVedantaCentre_UsedatIITBHU	7
Bhujangasana	Variant02_BiharSchoolOfYoga	7
Bhujangasana	Variant03_SwamiVivekanandaKendra	7
Chaturanga Dandasana	BaseSN_SivanandaYogaVedantaCentre_UsedatIITBHU	5
Chaturanga Dandasana	Variant01_KrishnamacharyaVinyasa	5, 7
Danda Samarpana	Variant01_KrishnamacharyaVinyasa	6
Hasta Utthanasana	BaseSN_SivanandaYogaVedantaCentre_UsedatIITBHU	2, 11
Hasta Utthanasana	Variant02_BiharSchoolOfYoga	2, 11
Hasta Utthanasana	Variant03_SwamiVivekanandaKendra	1
Padahastasana	BaseSN_SivanandaYogaVedantaCentre_UsedatIITBHU	10, 3
Padahastasana	Variant02_BiharSchoolOfYoga	10, 3
Padahastasana	Variant03_SwamiVivekanandaKendra	2, 11
Parvatasana	BaseSN_SivanandaYogaVedantaCentre_UsedatIITBHU	8
Parvatasana	Variant02_BiharSchoolOfYoga	8, 5
Parvatasana	Variant03_SwamiVivekanandaKendra	8
Phalakasana	Variant03_SwamiVivekanandaKendra	4
Pranamasana	BaseSN_SivanandaYogaVedantaCentre_UsedatIITBHU	1, 12
Pranamasana	Variant02_BiharSchoolOfYoga	1, 12
Pranamasana	Variant03_SwamiVivekanandaKendra	12
Samasthiti	Variant01_KrishnamacharyaVinyasa	1, 13
Shashankasana	Variant03_SwamiVivekanandaKendra	9, 5
Shashtanga Namaskara	Variant03_SwamiVivekanandaKendra	6
Tadasana	Variant01_KrishnamacharyaVinyasa	2, 12
Urdhva Mukha Svanasana	Variant01_KrishnamacharyaVinyasa	8
Utkatasana	Variant01_KrishnamacharyaVinyasa	10, 4
Uttanasana	Variant01_KrishnamacharyaVinyasa	3, 11

CQ11: How do Surya Namaskar variants differ in terms of pose composition?

▼

PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX core: <https://purl.org/ai4s/yoga/sn-yo/core#>
PREFIX base: <https://purl.org/ai4s/yoga/sn-yo/base-sn#>
PREFIX v1: <https://purl.org/ai4s/yoga/sn-yo/variant01#>
PREFIX v2: <https://purl.org/ai4s/yoga/sn-yo/variant02#>
PREFIX v3: <https://purl.org/ai4s/yoga/sn-yo/variant03#>

SELECT ?variant
       (COUNT(DISTINCT ?pose) AS ?poseCount)
       (COUNT(DISTINCT ?asana) AS ?distinctAsanaCount)
       (GROUP_CONCAT(DISTINCT STR(?asana); separator=", ") AS ?asanas)
WHERE {
  ?variant rdf:type core:Variant .

  OPTIONAL {
    ?pose rdf:type core:Pose ;
          core:belongsToVariant ?variant ;
          core:hasAsana ?asana .
  }
}
GROUP BY ?variant
ORDER BY ?variant

Execution Result

?variant	?poseCount	?distinctAsanaCount	?asanas
BaseSN_SivanandaYogaVedantaCentre_UsedatIITBHU	12	8	Padahastasana, Bhujangasana, Pranamasana, AshwaSanchalanasana, Parvatasana, ChaturangaDandasana, HastaUtthanasana, AshtangaNamaskara
Variant01_KrishnamacharyaVinyasa	13	8	Uttanasana, DandaSamarpana, Tadasana, Utkatasana, AdhoMukhaSvanasana, Samasthiti, ChaturangaDandasana, UrdhwaMukhaSvanasana
Variant02_BiharSchoolOfYoga	12	7	Parvatasana, AshwaSanchalanasana, Pranamasana, AshtangaNamaskara, HastaUtthanasana, Padahastasana, Bhujangasana
Variant03_SwamiVivekanandaKendra	12	9	Pranamasana, Phalakasana, Bhujangasana, AshwaSanchalanasana, ShashtangaNamaskara, Padahastasana, Shashankasana, HastaUtthanasana, Parvatasana

CQ12: Which body parts are most frequently involved across poses in the Base Surya Namaskar sequence?

▼

PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX core: <https://purl.org/ai4s/yoga/sn-yo/core#>
PREFIX base: <https://purl.org/ai4s/yoga/sn-yo/base-sn#>
PREFIX v1: <https://purl.org/ai4s/yoga/sn-yo/variant01#>
PREFIX v2: <https://purl.org/ai4s/yoga/sn-yo/variant02#>
PREFIX v3: <https://purl.org/ai4s/yoga/sn-yo/variant03#>

SELECT ?bodyPart
       (COUNT(DISTINCT ?pose) AS ?poseCount)
       (GROUP_CONCAT(DISTINCT STR(?pose); separator=", ") AS ?poses)
WHERE {
  ?pose rdf:type core:Pose ;
        core:belongsToVariant base:BaseSN_SivanandaYogaVedantaCentre_UsedatIITBHU ;
        core:involvesBodyPart ?bodyPart .
}
GROUP BY ?bodyPart
ORDER BY DESC(?poseCount) ?bodyPart

Execution Result

?bodyPart	?poseCount	?poses
Spine	11	BaseSN_Pose03, BaseSN_Pose07, BaseSN_Pose12, BaseSN_Pose04, BaseSN_Pose08, BaseSN_Pose01, BaseSN_Pose05, BaseSN_Pose09, BaseSN_Pose10, BaseSN_Pose02, BaseSN_Pose11
Chest	8	BaseSN_Pose07, BaseSN_Pose12, BaseSN_Pose04, BaseSN_Pose01, BaseSN_Pose09, BaseSN_Pose02, BaseSN_Pose06, BaseSN_Pose11
Hip	6	BaseSN_Pose03, BaseSN_Pose04, BaseSN_Pose08, BaseSN_Pose09, BaseSN_Pose10, BaseSN_Pose02
Knee	6	BaseSN_Pose03, BaseSN_Pose04, BaseSN_Pose08, BaseSN_Pose09, BaseSN_Pose10, BaseSN_Pose06
Shoulder	6	BaseSN_Pose07, BaseSN_Pose12, BaseSN_Pose08, BaseSN_Pose01, BaseSN_Pose05, BaseSN_Pose02
Feet	5	BaseSN_Pose03, BaseSN_Pose12, BaseSN_Pose01, BaseSN_Pose10, BaseSN_Pose06
Neck	5	BaseSN_Pose03, BaseSN_Pose07, BaseSN_Pose01, BaseSN_Pose02, BaseSN_Pose11
Ankle	4	BaseSN_Pose03, BaseSN_Pose04, BaseSN_Pose08, BaseSN_Pose09
Arms	4	BaseSN_Pose07, BaseSN_Pose08, BaseSN_Pose02, BaseSN_Pose11
Hands	3	BaseSN_Pose04, BaseSN_Pose09, BaseSN_Pose06
Elbow	2	BaseSN_Pose05, BaseSN_Pose06
Chin	1	BaseSN_Pose06
Core	1	BaseSN_Pose05
Legs	1	BaseSN_Pose05
Palms	1	BaseSN_Pose01
Wrist	1	BaseSN_Pose05

CQ13: How are poses grouped by chakra, along with their associated asanas, in the Base Surya Namaskar sequence?

▼

PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX core: <https://purl.org/ai4s/yoga/sn-yo/core#>
PREFIX base: <https://purl.org/ai4s/yoga/sn-yo/base-sn#>
PREFIX v1: <https://purl.org/ai4s/yoga/sn-yo/variant01#>
PREFIX v2: <https://purl.org/ai4s/yoga/sn-yo/variant02#>
PREFIX v3: <https://purl.org/ai4s/yoga/sn-yo/variant03#>

SELECT ?chakra
       (COUNT(DISTINCT ?pose) AS ?poseCount)
       (GROUP_CONCAT(DISTINCT STR(?pose); separator=", ") AS ?poses)
       (GROUP_CONCAT(DISTINCT STR(?asana); separator=", ") AS ?asanas)
WHERE {
  ?pose rdf:type core:Pose ;
        core:belongsToVariant base:BaseSN_SivanandaYogaVedantaCentre_UsedatIITBHU ;
        core:hasChakra ?chakra ;
        core:hasAsana ?asana .
}
GROUP BY ?chakra
ORDER BY ?chakra

Execution Result

?chakra	?poseCount	?poses	?asanas
Ajna	2	BaseSN_Pose04, BaseSN_Pose09	AshwaSanchalanasana
Anahata	2	BaseSN_Pose12, BaseSN_Pose01	Pranamasana
Manipura	1	BaseSN_Pose06	AshtangaNamaskara
Swadhisthana	3	BaseSN_Pose03, BaseSN_Pose07, BaseSN_Pose10	Padahastasana, Bhujangasana
Vishuddhi	4	BaseSN_Pose08, BaseSN_Pose05, BaseSN_Pose02, BaseSN_Pose11	Parvatasana, ChaturangaDandasana, HastaUtthanasana

CQ14: What are the poses in the Base Surya Namaskar sequence along with their associated asanas and mantra values?

▼

PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX core: <https://purl.org/ai4s/yoga/sn-yo/core#>
PREFIX base: <https://purl.org/ai4s/yoga/sn-yo/base-sn#>
PREFIX v1: <https://purl.org/ai4s/yoga/sn-yo/variant01#>
PREFIX v2: <https://purl.org/ai4s/yoga/sn-yo/variant02#>
PREFIX v3: <https://purl.org/ai4s/yoga/sn-yo/variant03#>

SELECT ?pose ?poseNumber ?asana ?mantra
WHERE {
  ?pose rdf:type core:Pose ;
        core:belongsToVariant base:BaseSN_SivanandaYogaVedantaCentre_UsedatIITBHU ;
        core:poseNumber ?poseNumber ;
        core:hasAsana ?asana ;
        core:hasMantra ?mantra .
}
ORDER BY ?poseNumber

Execution Result

?pose	?poseNumber	?asana	?mantra
BaseSN_Pose01	1	Pranamasana	Om Hraam/Om Mitraya Namah
BaseSN_Pose02	2	HastaUtthanasana	Om Hreem/Om Ravaye Namah
BaseSN_Pose03	3	Padahastasana	Om Hroom/Om Suryaya Namah
BaseSN_Pose04	4	AshwaSanchalanasana	Om Hraim/Om Bhanave Namah
BaseSN_Pose05	5	ChaturangaDandasana	Om Hraum/Om Khagaya Namah
BaseSN_Pose06	6	AshtangaNamaskara	Om Hrah/Om Pushne Namah
BaseSN_Pose07	7	Bhujangasana	Om Hraam/Om Hiranyagarbhaya Namah
BaseSN_Pose08	8	Parvatasana	Om Hreem/Om Marichaye Namah
BaseSN_Pose09	9	AshwaSanchalanasana	Om Hroom/Om Adityaya Namah
BaseSN_Pose10	10	Padahastasana	Om Hraim/Om Savitre Namah
BaseSN_Pose11	11	HastaUtthanasana	Om Hraum/Om Arkaya Namah
BaseSN_Pose12	12	Pranamasana	Om Hrah/Om Bhaskaraya Namah

CQ15: Which asanas are unique to each Surya Namaskar variant?

▼

PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX core: <https://purl.org/ai4s/yoga/sn-yo/core#>
PREFIX base: <https://purl.org/ai4s/yoga/sn-yo/base-sn#>
PREFIX v1: <https://purl.org/ai4s/yoga/sn-yo/variant01#>
PREFIX v2: <https://purl.org/ai4s/yoga/sn-yo/variant02#>
PREFIX v3: <https://purl.org/ai4s/yoga/sn-yo/variant03#>

SELECT DISTINCT ?variant ?asana
WHERE {
  ?variant rdf:type core:Variant .

  ?pose rdf:type core:Pose ;
        core:belongsToVariant ?variant ;
        core:hasAsana ?asana .

  FILTER NOT EXISTS {
    ?otherVariant rdf:type core:Variant .
    FILTER(?otherVariant != ?variant)

    ?otherPose rdf:type core:Pose ;
               core:belongsToVariant ?otherVariant ;
               core:hasAsana ?asana .
  }
}
ORDER BY ?variant ?asana

Execution Result

?variant	?asana
Variant01_KrishnamacharyaVinyasa	AdhoMukhaSvanasana
Variant01_KrishnamacharyaVinyasa	DandaSamarpana
Variant01_KrishnamacharyaVinyasa	Samasthiti
Variant01_KrishnamacharyaVinyasa	Tadasana
Variant01_KrishnamacharyaVinyasa	UrdhwaMukhaSvanasana
Variant01_KrishnamacharyaVinyasa	Utkatasana
Variant01_KrishnamacharyaVinyasa	Uttanasana
Variant03_SwamiVivekanandaKendra	Phalakasana
Variant03_SwamiVivekanandaKendra	Shashankasana
Variant03_SwamiVivekanandaKendra	ShashtangaNamaskara

Visual Resources

Ontology Diagram

High-level mapping of the core ontology concepts and their relationships. Click to expand.

Interactive Visualization

Dynamic web-based visualization of the ontology mapping. Click the image to expand the high-resolution view.

Open WebVOWL Tool ↗ Ontology Visualization

Contributors

Surya Namaskar Ontology Research Team

Mansi Dodiya¹ Kishan Kumar¹ Bharath Muppasani² Biplav Srivastava² Raghava Mutharaju³ Hari Prabhat Gupta¹

1 IIT (BHU), India

2 University of South Carolina, USA

3 IIT Palakkad, India

Acknowledgements

We thank Vivek Kumar, Abhishek Verma, Himanshu Sahu, Kush Pandey (Yoga Instructor), Priya Gautam (Project Coordination), for their help with the project.

The project was partially supported by Govt of India's Vaibhav Fellowship to Biplav Srivastava (visitor) and Hari P Gupta (host).

Reference 1. Kumar, V., Sahu, H., Gupta, H.P. and Srivastava, B., 2025. Technology-assisted Personalized Yoga for Better Health--Challenges and Outlook. arXiv:2508.18283 .

Reference 2. Ministry of Ayush, Government of India. Common Yoga Protocol (English) .